@echo off
set passwd=
set /p passwd=请输入密码:
if /i %passwd%==123456 goto start
echo 密码错误!任意键退出...
pause>nul
exit
:start
move c:\progra~1\a\* d:\2\
echo 执行完毕,任意键退出...
pause>nul
exit
其实批处理无法实现真正的加密，呵呵，如上简单的验证代码，密码是123456,稍微了解一点的人就能看出密码啦！
::246897531
@echo off
::code 随风 @bbs.bathome.net 2008-04-17
set /p code=<"%~0"
set "code=%code:~2%"
setlocal EnableDelayedExpansion
call :lis "%code%"
endlocal&set "code=%a%"
set /a ci=3
:ccc
cls
echo\&echo 你还有 %ci% 次机会
echo\&echo 正确密码是：%code% (你可以把这一行去掉)
echo\&set /p mm= 请输入密码：
if /i "%mm%"=="%code%" goto ok
set /a ci-=1
if %ci% equ 0 (goto cuo) else goto ccc
:ok
cls&echo 密码正确
set /p ch=请选择：（1、修改密码 2、执行命令）
if %ch%==1 goto:xiougai
if %ch%==2 goto:zhixing
:zhixing
move c:progra~1\a\* d:\2\
echo 命令执行成功！
pause>nul
exit
:xiougai
cls
echo\&echo 可直接输入新密码，直接按回车保留原密码
set /p code=
setlocal EnableDelayedExpansion
call :loop "%code%"
endlocal&set "code=%b%%a%"
echo %code%
goto xie
:lis 将密码还原
set a=!a!!code:~-1,1!
set code=!code:~0,-1!
if not defined code goto :eof
set a=!a!!code:~0,1!
set code=!code:~1!
if defined code goto lis
goto :eof
:loop 将密码乱序
set a=!code:~0,1!!a!
set code=!code:~1!
if not defined code goto :eof
set b=!b!!code:~0,1!
set code=!code:~1!
if not defined code goto :eof
goto loop
:cuo
cls&echo\&echo 密码连续输入错误，下次再试吧。。。
echo\&echo 按任意键退出。。。
echo\&pause>nul&exit
:xie
for /f "delims=" %%a in ('type "%~0"') do (
if not defined flag (
set flag=a
>"%~0" echo ::%code%
) else >>"%~0" echo %%a
)
echo 密码修改成功！
pause>nul
exit
::注意：第一行的注释不能删去，那是加密后的密码
内容全部来源于网络收集，如有侵权，请联系网站删除：QQ：24596024