58问答库 > 安装vim补全插件过程遇到的问题，我按如下安装，到第二步的 .vimrc 怎么找不到？谢谢

安装vim补全插件过程遇到的问题，我按如下安装，到第二步的 .vimrc 怎么找不到？谢谢

2025-03-12 16:06:49

推荐回答（2个）

回答（1）：

只要在 vim 里：

:e $MYVIMRC

VIM 就会打开你的 vimrc 文件。如果没有就会创建一个。

有 vimrc 文件后，vim 默认就会是非兼容模式。不过习惯上，最好还是加上：

set nocompatible

这句如果有，必须是 vimrc 的第一句。因为改变它的值，会使很多选项产生连锁变化，即副作用很大。

这是 vim 自带的 vimrc 例子，如果你没有自己的，从这里开始是个不错的注意。

" An example for a vimrc file.
"
" Maintainer:    Bram Moolenaar 
" Last change:    2011 Apr 15
"
" To use it, copy it to
"     for Unix and OS/2:  ~/.vimrc
"          for Amiga:  s:.vimrc
"  for MS-DOS and Win32:  $VIM\_vimrc
"        for OpenVMS:  sys$login:.vimrc

" When started as "evim", evim.vim will already have done these settings.
if v:progname =~? "evim"
  finish
endif

" Use Vim settings, rather than Vi settings (much better!).
" This must be first, because it changes other options as a side effect.
set nocompatible

" allow backspacing over everything in insert mode
set backspace=indent,eol,start

if has("vms")
  set nobackup        " do not keep a backup file, use versions instead
else
  set backup        " keep a backup file
endif
set history=50        " keep 50 lines of command line history
set ruler        " show the cursor position all the time
set showcmd        " display incomplete commands
set incsearch        " do incremental searching

" For Win32 GUI: remove 't' flag from 'guioptions': no tearoff menu entries
" let &guioptions = substitute(&guioptions, "t", "", "g")

" Don't use Ex mode, use Q for formatting
map Q gq

" CTRL-U in insert mode deletes a lot.  Use CTRL-G u to first break undo,
" so that you can undo CTRL-U after inserting a line break.
inoremap  u

" In many terminal emulators the mouse works just fine, thus enable it.
if has('mouse')
  set mouse=a
endif

" Switch syntax highlighting on, when the terminal has colors
" Also switch on highlighting the last used search pattern.
if &t_Co > 2 || has("gui_running")
  syntax on
  set hlsearch
endif

" Only do this part when compiled with support for autocommands.
if has("autocmd")

  " Enable file type detection.
  " Use the default filetype settings, so that mail gets 'tw' set to 72,
  " 'cindent' is on in C files, etc.
  " Also load indent files, to automatically do language-dependent indenting.
  filetype plugin indent on

  " Put these in an autocmd group, so that we can delete them easily.
  augroup vimrcEx
  au!

  " For all text files set 'textwidth' to 78 characters.
  autocmd FileType text setlocal textwidth=78

  " When editing a file, always jump to the last known cursor position.
  " Don't do it when the position is invalid or when inside an event handler
  " (happens when dropping a file on gvim).
  " Also don't do it when the mark is in the first line, that is the default
  " position when opening a file.
  autocmd BufReadPost *
    \ if line("'\"") > 1 && line("'\"") <= line("$") |
    \   exe "normal! g`\"" |
    \ endif

  augroup END

else

  set autoindent        " always set autoindenting on

endif " has("autocmd")

" Convenient command to see the difference between the current buffer and the
" file it was loaded from, thus the changes you made.
" Only define it when not defined already.
if !exists(":DiffOrig")
  command DiffOrig vert new | set bt=nofile | r ++edit # | 0d_ | diffthis
          \ | wincmd p | diffthis
endif

回答（2）：

没有就新建一个，缺省.vimrc是没有的

最新问答

51talk无忧英语和沪江网校效果哪个好，靠谱

想练侧空翻，但是不敢，怕头碰地，怎么练，不知技巧

皮卡车前车盖怎么开？

安装vim补全插件过程遇到的问题，我按如下安装，到第二步 的 .vimrc 怎么找不到？谢谢

安装vim补全插件过程遇到的问题，我按如下安装，到第二步的 .vimrc 怎么找不到？谢谢